|
其實做小偷是很容易的.......................
要做一名好的小偷有點難度:P
這是我投給電腦報的一篇稿子,很簡單,寫得很倉促,有很多不足的地方,高手們笑的時候麻煩指正一下,原文是拿ALEXA開刀,我在落伍發表的時候修改成了QQ天氣預報小偷.
靈活運用XMLHTTP組件
你也可以做“小偷”
看到這個標題你可千萬別誤會，這里所說的“小偷”指的是在ASP中運用XML中的XMLHTTP組件提供的強大功能，把遠程網站上的數據（圖片，網頁及其他文件）抓取到本地，經過各種處理后顯示到頁面上或者存儲進數據庫的一類程序。你可以通過這種小偷程序，完成過去一些似乎完全不可能實現的任務，比如說把某個站的頁面偷梁換柱后變成自己的頁面，或者把某個站的一些數據（文章，圖片）保存到本地數據庫中加以利用。“小偷”的優點有：無須維護網站，因為小偷程序中的數據來自其他網站，它將隨著該網站的更新而更新；可以節省大量的服務器資源，一般小偷程序就幾個文件，所有網頁內容都是來自其他網站。缺點在于：不穩定，如果目標網站出錯，程序也會出錯，而且，如果目標網站進行升級維護，那么小偷程序也要進行相應修改；速度，因為是遠程調用，速度和在本地服務器上讀取數據比起來，肯定要慢一些。怎么樣，聽起來很神奇吧？我們現在就開始來學習一些“小偷”程序的入門知識吧！
我們拿個簡單點的東西來研究一下吧，QQ網站上的天氣預報程序
程序演示地址：http://www.gtocn.com/tianqi.asp
源碼下載：http://www.gtocn.com/tianqi.txt
代碼如下：
<%
On Error Resume Next
Server.ScriptTimeOut=9999999
Function getHTTPPage(Path)
t = GetBody(Path)
getHTTPPage=BytesToBstr(t,"GB2312")
End function
'首先，進行小偷程序的一些初始化設置，以上代碼的作用分別是忽略掉所有非致命性錯誤，把小偷程序的運行超時時間設置得很長（這樣不會出現運行超時的錯誤），轉換原來默認的UTF-8編碼轉換成GB2312編碼，否則直接用XMLHTTP組件調用有中文字符的網頁得到的將是亂碼。
Function GetBody(url)
on error resume next
Set Retrieval = CreateObject("Microsoft.XMLHTTP")
With Retrieval
.Open "Get", url, False, "", ""
.Send
GetBody = .ResponseBody
End With
Set Retrieval = Nothing
End Function
'然后調用XMLHTTP組件創建一個對象并進行初始化設置。
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function
Function Newstring(wstr,strng)
Newstring=Instr(lcase(wstr),lcase(strng))
if Newstring<=0 then Newstring=Len(wstr)
End Function
'處理抓取回來的數據需要調用adodb.stream組件并進行初始化設置。%>
'以下即為頁面顯示部分
<%
Dim wstr,str,url,start,over,city
'定義一些需要使用到的變量
city = Request.QueryString("id")
'程序傳回的ID變量（即用戶選擇的城市）賦給id
url="http://appnews.qq.com/cgi-bin/news_qq_search?city="&city&""
'這里設置需要抓取的頁面地址，當然你也可以直接指定某個地址而不使用變量
wstr=getHTTPPage(url)
'獲取指定頁面的全部數據
start=Newstring(wstr," <html>")
'這里設置需要處理的數據的頭部，這個變量應視不同情況而設置，具體內容可以通過查看需要抓取的頁面的源代碼來確定。因為在這個程序里我們需要抓取整個頁面,所以設置為頁面全部抓取。注意，設置的內容必須是頁面內容唯一的，不可以重復。
over=Newstring(wstr," </HTML>")
'和start相對應的就是需要處理的數據的尾部，同樣的，設置的內容必須是頁面中唯一的。
body=mid(wstr,start,over-start)
'設置顯示頁面的范圍
'下面就是動用乾坤挪移大法的時候了，通過replace可以用一些字符替換掉數據中指定的字符。
body = replace(body,"skin1","天氣預報 - 斯克網絡")
body = replace(body,"http://appnews.qq.com/cgi-bin/news_qq_search?city","tianqi.asp?id")
'本程序中已經完成了替換的工作，如果有其他需要的話可以繼續進行類似的替換操作。
response.write body
%>
替換完需要修改的內容后，就可以把修改的內容顯示在頁面上了。至此程序結束
程序使用方法及結果：把上述代碼去掉說明部分后保存為tianqi.asp，上傳到支持ASP和XML的空間下，在瀏覽器中運行即可。你可以在在這個程序的基礎上進行進一步的界面美化或者程序優化。
以上只是一些關于XMLHTTP組件的初級應用，實際上它還能實現的功能還有很多，比如說保存遠程圖片到本地服務器上，配合adodb.stream組件可以把獲取來的數據保存進數據庫。小偷的作用和使用范圍都很廣。但是不可以拿來做違法的事哦！
也許還有人要問了，這種“小偷”程序難道只是ASP的專利嗎？非也，PHP通過fopen函數一樣可以實現同樣的效果，由于PHP本身的各種特點，寫出來的小偷程序和ASP相比，在體積和執行效率上都有者明顯的優勢，但限于篇幅，這里就不一一說明了。
最后，感謝對本文有重大貢獻的落伍者論壇的西瓜，allen和CN,HYDNS。大家如果有任何疑問或者見解可以訪問我們的論壇來進行溝通交流，論壇地址:http://www.im286.com
（出處：落伍者論壇）
|
