很多 Windows 程序使用的窗口都帶有使用拆分器分隔的窗格。你可以拖動拆分器來擴大其中一個窗格同時縮小其它的窗格——而這個過程無須更改父窗口的大小。雖然 Visual Basic 6 不提供用于這一用途的控件，但是你可以自己實現這一效果。

　　創建窗格拆分器的方法是使用一個 Picture Box 控件作為其它控件的容器。在設計窗體時，放兩個 Picture Box 控件到窗體上，每個代表一個窗格。例如，對于上部窗格和下部窗格，可以將它們叫做pbTop和pbBotton。然后，將其它控件放在每個窗格對應的 Picture Box 上。

　　在程序運行時，程序代碼調整兩個 Picture Box 控件（即兩個窗格）的大小從而以預定義的尺寸填充窗口。Picture Box 控件的尺寸會被精確地計算，以使窗體在兩個 Picture Box 之間顯示一個窄帶；這個窄帶就作為拆分器。

　　將窗體的MousePointer屬性設計為“7 - Size NS”，以使得在鼠標置于拆分器之上時光標形狀變為調整上/下大小的樣式。將每個 Picture Box 控件的MousePointer屬性設置為“1 - Arrow”。程序還需要一些常量設置拆分器的高度和每個窗格允許的最小高度。

　　下面拆分器的工作方式：在用戶開始拖到拆分器時，拆分器的新位置由鼠標光標的位置所決定。這由MouseMove事件過程實現。在MouseMove事件過程中首先一個叫做ChangePaneSizes的過程被調用；該過程使用新的拆分器位置相應地更改兩個窗格的尺寸。任何一個窗格的尺寸都不能小于指定的最小尺寸。

　　下面的完成這一動作的代碼。你可以創建一個 VB 程序親自試一下這段代碼，首先在窗體上放置兩個 Picture Box 控件，分別命名為pbTop和pbBottom；然后，將這段代碼粘貼到窗體的代碼窗口中。這個例子展示的是一個水平拆分器分隔兩個窗格，但是你可以對它進行修改，從而得到其它的窗格排列樣式。

　　Option Explicit

　　Const SPLITTER_HEIGHT = 40
　　Const MIN_PANE_HEIGHT = 400

　　' The percentage of the window height
　　' occupied by the top pane.
　　Dim TopPanePercent As Single
　　' True when the splitter is being dragged.
　　Private Dragging As Boolean

　　Private Sub ChangePaneSizes()

　　' Arrange the panes according to the new splitter position.
　　Dim TopHeight As Single
　　Dim BottomHeight As Single

　　' Do nothing if window is minimized.
　　If WindowState = vbMinimized Then Exit Sub

　　TopHeight = (ScaleHeight - SPLITTER_HEIGHT) * TopPanePercent
　　If TopHeight < MIN_PANE_HEIGHT Then TopHeight = MIN_PANE_HEIGHT
　　pbTop.Move 0, 0, ScaleWidth, TopHeight
　　BottomHeight = (ScaleHeight - SPLITTER_HEIGHT) - TopHeight
　　If BottomHeight >= MIN_PANE_HEIGHT Then
　　pbBottom.Move 0, TopHeight + SPLITTER_HEIGHT, ScaleWidth, BottomHeight
　　End If

　　End Sub

　　Private Sub Form_Load()
　　' Initially each pane gets half the window.
　　TopPanePercent = 0.5
　　End Sub

　　Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, _
　　Y As Single)
　　' Start dragging the splitter.
　　Dragging = True
　　End Sub

　　Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, _
　　Y As Single)
　　' As the splitter is dragged.
　　' Do nothing if we're not dragging.
　　If Not Dragging Then Exit Sub

　　TopPanePercent = Y / ScaleHeight
　　If TopPanePercent < 0 Then TopPanePercent = 0
　　If TopPanePercent > 1 Then TopPanePercent = 1
　　ChangePaneSizes
　　End Sub

　　Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, _
　　Y As Single)
　　' End dragging the splitter.
　　Dragging = False
　　End Sub

　　Private Sub Form_Resize()
　　' Change pane sizes if the window is resized.
　　ChangePaneSizes
　　End Sub