五、使用記錄集時是否應該創建單獨的連接對象？
要正確地回答這個問題，我們必須分析兩種不同條件下的測試：第一，頁面只有一個數據庫事務；第二，頁面有多個數據庫事務。

在前例中，我們創建了一個單獨的Connection對象并將它賦給Recordset的ActiveConnection屬性。然而，如ADO__03.asp所示，我們也可以直接把連接串賦給ActiveConnection屬性，在腳本中初始化和配置Connection對象這一額外的步驟可以省去。
objRS.ActiveConnection = Application("Conn")

雖然Recordset對象仍舊要創建一個連接，但此時的創建是在高度優化的條件下進行的。因此，與上一次測試相比，頁面開銷又下降了23%，而且如預期的一樣，單個記錄的顯示時間沒有實質的變化。

因此，我們的第二個規則如下：

如果只使用一個記錄集，直接把連接串賦給ActiveConnection屬性。
接下來我們檢查頁面用到多個記錄集時，上述規則是否仍舊有效。為測試這種情形，我們引入一個FOR循環將前例重復10次。在這個測試中，我們將研究三種變化：

第一，如ADO__04.asp所示，在每一個循環中建立和拆除Connection對象：
Dim i
For i = 1 to 10

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = objConn
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing
objConn.Close
Set objConn = Nothing

Next




第二，如ADO__05.asp所示，在循環外面創建Connection對象，所有記錄集共享該對象：
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("Conn")

Dim i
For i = 1 to 10
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = objConn
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing

Next
objConn.Close
Set objConn = Nothing

第三，如ADO__06.asp所示，在每一個循環內把連接串賦給ActiveConnection屬性：
Dim i
For i = 1 to 10

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.ActiveConnection = Application("Conn")
objRS.CursorType = 0 'adOpenForwardOnly
objRS.LockType = 1 'adLockReadOnly
objRS.Open Application("SQL")

If objRS.EOF Then
Response.Write("No Records Found")
Else
'write headings
...
'write data
...
End If

objRS.Close
Set objRS = Nothing
Next

就象我們可以猜想到的一樣，在循環內創建和拆除連接對象是效率最差的方法。不過，令人驚異的是，在循環內直接把連接串賦給ActiveConnection屬性只比共享單個連接對象稍微慢了一點。

盡管如此，第三規則應該為：

同一頁面內用到多個記錄集時，創建單一的連接對象并通過ActiveConnection屬性共享它。
（出處：熱點網絡）