|
簡介
首先簡單介紹一下有關(guān)加密的背景。由于美國禁止幾種密碼算法的對外出口的
加密位數(shù)（例如SSL的40位加密限制），本文將介紹一種ASP可以使用的簡單字符加密算法，
而不是那些受限制的加密算法。其實，這里介紹的加密算法對于一般的運用來說已經(jīng)足夠
解密人麻煩一陣子的了。它的加密基礎(chǔ)是最簡單的Vernum密碼方法，我將在下一篇文章中
介紹這種密碼。
它的基本原理是，需要有一個需要加密的明文和一個隨機生成的解密鑰匙文件。然后
使用這兩個文件組合起來生成密文。
(明文) 組合 (密鑰) = 加密后的密文
所以本文介紹的是生成密鑰的代碼。我們假設(shè)我們生成的密鑰為512位長的密鑰，
它已經(jīng)足夠來加密一個文本字符了。代碼如下：
KeyGeN.asp文件
<%
'******************************
' KeyGeN.asp
'******************************
Const g_KeyLocation = "C:key.txt"
Const g_KeyLen = 512
On Error Resume Next
Call WriteKeyToFile(KeyGeN(g_KeyLen),g_KeyLocation)
if Err <> 0 Then
Response.Write "ERROR GENERATING KEY." & "<P>"
Response.Write Err.Number & "<BR>"
Response.Write Err.Description & "<BR>"
Else
Response.Write "KEY SUCCESSFULLY GENERATED."
End If
Sub WriteKeyToFile(MyKeyString,strFileName)
Dim keyFile, fso
set fso = Server.CreateObject("scripting.FileSystemObject")
set keyFile = fso.CreateTextFile(strFileName, true)
keyFile.WriteLine(MyKeyString)
keyFile.Close
End Sub
Function KeyGeN(iKeyLength)
Dim k, iCount, strMyKey
lowerbound = 35
upperbound = 96
Randomize ' Initialize random-number generator.
for I = 1 to iKeyLength
s = 255
k = Int(((upperbound - lowerbound) + 1) * Rnd + lowerbound)
strMyKey = strMyKey & Chr(k) & ""
next
KeyGeN = strMyKey
End Function
%>
在IIS下運行上面的KeyGeN.asp頁面。你只需要如此做一次，他將把密鑰寫入文件
c:key.txt中 (如果你愿意的話，你也可以把這個文件放到另外一個更加安全的地方).
然后你可以打開這個key.txt文件，它將包含512個ASCII碼在35到96之間的字符.
并且由于是隨機生成的，所以每個人的私人密鑰文件key.txt將是不一樣的，下面是
一個例子密鑰文件：
IY/;$>=3)?^-+7M32#Q]VOII.Q=OFMC`:P7_B;<R/8U)XFHC<SR_E$.DLG'=I+@5%*+OP:F_=';'
NSY`-^S.`AA=BJ3M0.WF#T5LGK(=/<:+C2K/^7AI$;PU'OME2+T8ND?W$C(J,;631'M-LD5F%%1
TF_&K2A-D-54[2P,#'*JU%6`0RF3CMF0(#T07U'FZ=>#,+.AW_/+']DIB;2DTIA57TT&-)O'/*F'
M>H.XH5W^0Y*=71+5*^`^PKJ(=E/X#7A:?,S>R&T;+B#<:-*@)X9F`_`%QA3Z95.?_T#1,$2#FW
W5PBH^*<])A(S0@AVD8C^Q0R^T1D?(1+,YE71X+.*+U$:3XO^Q].KG&0N0];[LJ<OZ6IN?7N4<GT
L?(M'4S8+3JMK5]HC%^1^+K;$WBXPA?F&5^ED$7%*O/U[1/?8(5:1OVWV*1Z-%`:K&V?X1,1KU
RD@3W0^D)<OG40?(VJ4EWL5A5M<$A);CQ36R9I]*U#Q%1<Y&SA%#1<V
下面再仔細分析一下上面的程序，我們發(fā)現(xiàn)其中的lowerbound和upperbound的數(shù)值
其實就是你想使用來加密的ASCII字符范圍。
在第一部分，討論了如何生成密鑰，下面將介紹如何使用這個密鑰來加密和解密一個字符串。
下面的代碼就是能夠同時實現(xiàn)這個功能的函數(shù)
Crypt.asp文件
<%
Dim g_Key
Const g_CryptThis = "Now is the time for all good men to come to the aid of their country."
Const g_KeyLocation = "c:key.txt"
g_Key = mid(ReadKeyFromFile(g_KeyLocation),1,Len(g_CryptThis))
Response.Write "<p>ORIGINAL STRING: " & g_CryptThis & "<p>"
Response.Write "<p>KEY VALUE: " & g_Key & "<p>"
Response.Write "<p>ENCRYPTED CYPHERTEXT: " & EnCrypt(g_CryptThis) & "<p>"
Response.Write "<p>DECRYPTED CYPHERTEXT: " & DeCrypt(EnCrypt(g_CryptThis)) & "<p>"
Function EnCrypt(strCryptThis)
Dim strChar, iKeyChar, iStringChar, I
for I = 1 to Len(strCryptThis)
iKeyChar = Asc(mid(g_Key,I,1))
iStringChar = Asc(mid(strCryptThis,I,1))
' *** uncomment below to encrypt with addition,
' iCryptChar = iStringChar + iKeyChar
iCryptChar = iKeyChar Xor iStringChar
strEncrypted = strEncrypted & Chr(iCryptChar)
next
EnCrypt = strEncrypted
End Function
Function DeCrypt(strEncrypted)
Dim strChar, iKeyChar, iStringChar, I
for I = 1 to Len(strEncrypted)
iKeyChar = (Asc(mid(g_Key,I,1)))
iStringChar = Asc(mid(strEncrypted,I,1))
' *** uncomment below to decrypt with subtraction
' iDeCryptChar = iStringChar - iKeyChar
iDeCryptChar = iKeyChar Xor iStringChar
strDecrypted = strDecrypted & Chr(iDeCryptChar)
next
DeCrypt = strDecrypted
End Function
Function ReadKeyFromFile(strFileName)
Dim keyFile, fso, f
set fso = Server.CreateObject("Scripting.FileSystemObject")
set f = fso.GetFile(strFileName)
set ts = f.OpenAsTextStream(1, -2)
Do While not ts.AtEndOfStream
keyFile = keyFile & ts.ReadLine
Loop
ReadKeyFromFile = keyFile
End Function
%>
在Crypt.asp中我們首先從密鑰文件中得到密鑰值，然后從這段密鑰中
截取和我們需要加密的明文同樣長度的密鑰。然后使用一個簡單的異或操作
將明文和密鑰進行運算，那么得到的結(jié)果就是加密后的密文了。過程很簡單的。
由于是使用了異或操作，所以解密將非常簡單，只要使用同樣的密鑰對密文
再次進行異或操作就能夠解密了。
在上面介紹的基礎(chǔ)上，你可以少加改動，就可以使用同樣的方法加密一個文件。
唯一需要注意的是，對于一個二進制文件，你需要做一些完整性檢查以保證轉(zhuǎn)換回來
的字符不要越界。
現(xiàn)在你需要做的就是把密鑰保存在服務(wù)器上的一個安全的地方（不能夠被外部訪問）
附注：
Vernam密碼是由Gilbert Vernam (他是AT&T的工程師)在1918年發(fā)明的。
這是一種使用異或方法進行加密解密的方法。
|
