我們在處理日常工作的時候，函數是一個不可缺少的部分，Excel中除了有vlookup等萬能查詢函數，還有我們必須要熟悉的sumproduct函數，它可以實現求和、單一多條件和復雜情況下的各類計數及綜合排名等數據處理，今天我們就來學習一下這個函數的全部9種用法。

用法1：簡單數組求和

案例：求出所有人員最終的補貼之和

函數1=SUMPRODUCT(D3:D8,E3:E8)

函數2=SUMPRODUCT(D3:D8*E3:E8)

案例講解：sumproduct函數將相應元素之間通過相乘并求和計算，可以用逗號或是用*號進行連接，返回相應的數組或區域乘積的和。數組設計的區域必須是相同的，如基礎補貼區域為：D3:D8，難度系數選擇的范圍也是3-8。這里實現的效果也可以是將每一個值相乘后再相加，結果都是一樣的5960。

用法2：別具一格的單一條件計數

案例：求出男女人數

男=SUMPRODUCT(N($D$3:$D$8=H5))

女=SUMPRODUCT(N($D$3:$D$8=H6))

案例講解：在計數的時候我們在中間使用了N函數，這個函數代表將True的值轉化為1，將False的值轉換為0，最后sumproduct函數將所有符合條件的值進行求和。我們可以選擇N($D$3:$D$8=H5)函數之后，按F9進行函數解析為：SUMPRODUCT({1;0;1;1;0;1})。

用法3：比sumifs更簡單的多條件數據求和

案例：求出男員工中難度系數在1以上的總的工作完成度。

函數=SUMPRODUCT(($D$4:$D$9="男")*($F$4:$F$9>1)*($E$4:$E$9))

函數解析：在多條件求和中，我們的操作方法跟用法1一致，將多個條件用*進行連接即可實現。

用法4：比countifs看起來更舒服的多條件計數

案例：求工作完成度大于5的男員工人數。

函數=SUMPRODUCT(($D$4:$D$9="男")*($E$4:$E$9>5))

案例講解：操作方法同用法3，唯一的不同是后面沒有再*數值，所以我們最終的結果只是將符合條件的個數進行求和。選擇($D$4:$D$9="男")*($E$4:$E$9>5)，按F9最終的結果會解析為如下：

用法5：不一樣的綜合多參數綜合權重排名

案例：將人員按照工作完成度、執行力、滿意度等不同維度占比進行綜合排名。

函數=SUMPRODUCT($D$3:$F$3,D4:F4)

案例講解：首先通過用sumproduct函數進行綜合得分的計算，最后用RANK函數進行最終的數據排名。

用法6：不同條件下的跨列數據求和

案例：計算第一季度每個人的目標值及最終完成值。

目標=SUMPRODUCT((D$3:I$3=$J$3)*($D4:$I4))

實際=SUMPRODUCT((D$3:I$3=$K$3)*($D4:$I4))

案例講解：在多條件求和的情況下，這個函數會比sumifs來的更加簡單。

用法7：最快速度的數據拆分展示

案例：將左邊按豎排展示的數據最快轉換為右邊的多維數據展示

函數=SUMPRODUCT(($B$3:$B$14=$G3)*($C$3:$C$14=H$2)*($D$3:$D$14))

案例講解：這個方法與多條件數據求和方法一樣，利用好相對引用和絕對引用就可以實現數據的最快速度轉化顯示。

用法8：求出銷量排名前三產品的總銷售量

案例：求出A-G產品中銷量排名前三的總銷售量

函數=SUMPRODUCT(LARGE($C$4:$C$10,ROW(1:3)))

案例解析：在這里我們使用了一個返回值的函數LARGE函數，他的作用在于可以返回區域中排名多少位的值。我們通過用ROW來返回1-3對應的數值，加上sumproduct函數的數組計算的特點，這樣就可以實現排名前多少對應的總量。

用法9：求出今天倉庫總共出庫了多少種產品

函數=SUMPRODUCT(1/COUNTIF($C$3:$C$14,$C$3:$C$14))

案例講解：在這里我們主要通過用countif函數計算出每種產品出現了多少次，再用1/countif，這樣可以將出現的多的次數進行分解，選擇countif函數按F9可以得到如下：

所以最后用1來除的時候，就可以將出現2次的改為2個1/2，出現3次的改為3個1/3。最后求和即可。